I just got my Nano RP2040 Connect and discovered that the Arduino team has recently completely revamped their online documentation as described in this blog post on May 17: https://blog.arduino.cc/2021/05/17/arduino-docs-has-all-the-info-you-ever-need-about-arduino-boards/ .

 

And here is the link to the new docs homepage: https://docs.arduino.cc/

 

The boards are organized by families:

  • MKR
  • Classic
  • Nano

 

The Portenta has been split off into a separate Arduino Pro Documentation page.

 

Perfect time to check out how things have changed by looking at the Nano RP2040 Connect docs.

 

I like the new organization and layout, it's easy to jump right in and get started.

 

 

The Tutorials section is really nice in that it showcases a lot of the board features.

 

 

 

Another feature that I also appreciated is the Full Pinout document that has 6 different pinout diagrams that save you from having to decipher variant.h files.

 

One shows how the multiplexed IO resources are assigned:

And another one that is really helpful, shows how the onboard peripherals are connected:

 

Really great stuff.  Very well done.

 

So, I'll jump right in and try a tutorial .   I wanted to try the WiFi, so I tried the Web server tutorial that allows control of the onboard RGB LED from a remote browser window ("Control built-in RGB LED over Wi-Fi with Nano RP2040 Connect").  One thing I discovered is that the RGB LED is connected through the W-102 module which means that you would need to include the WiFiNINA library even if you weren't going to use the WiFi.  Another thing I discovered is that my installed WiFiNINA library was out of date and the initial compile failed, but that was an easy fix - just updated to the latest version.

 

Here's the code:

 

Nano_RP2040_Connect_WiFi_LED.ino

#include <SPI.h>
#include <WiFiNINA.h>
#include "arduino_secrets.h"


///////please enter your sensitive data in the Secret tab/arduino_secrets.h
//char ssid[] = "";        // your network SSID (name)
//char pass[] = "";    // your network password (use for WPA, or use as key for WEP)
//int keyIndex = 0;                 // your network key index number (needed only for WEP)


int status = WL_IDLE_STATUS;
WiFiServer server(80);


void setup() {
  pinMode(LEDR, OUTPUT);
  pinMode(LEDG, OUTPUT);
  pinMode(LEDB, OUTPUT);
  Serial.begin(9600);      // initialize serial communication


  while (!Serial);


  // check for the WiFi module:
  if (WiFi.status() == WL_NO_MODULE) {
    Serial.println("Communication with WiFi module failed!");
    // don't continue
    while (true);
  }


  String fv = WiFi.firmwareVersion();
  if (fv < WIFI_FIRMWARE_LATEST_VERSION) {
    Serial.println("Please upgrade the firmware");
  }


  // attempt to connect to WiFi network:
  while (status != WL_CONNECTED) {
    Serial.print("Attempting to connect to Network named: ");
    Serial.println(ssid);                   // print the network name (SSID);


    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:
    status = WiFi.begin(ssid, pass);
    // wait 10 seconds for connection:
    delay(10000);
  }
  server.begin();                           // start the web server on port 80
  printWifiStatus();                        // you're connected now, so print out the status
}




void loop() {
  WiFiClient client = server.available();   // listen for incoming clients


  if (client) {                             // if you get a client,
    Serial.println("new client");           // print a message out the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    while (client.connected()) {            // loop while the client's connected
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        if (c == '\n') {                    // if the byte is a newline character


          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println();


            // the content of the HTTP response follows the header:
            client.print("<style>");
            client.print(".container {margin: 0 auto; text-align: center; margin-top: 100px;}");
            client.print("button {color: white; width: 100px; height: 100px;");
            client.print("border-radius: 50%; margin: 20px; border: none; font-size: 20px; outline: none; transition: all 0.2s;}");
            client.print(".red{background-color: rgb(196, 39, 39);}");
            client.print(".green{background-color: rgb(39, 121, 39);}");
            client.print(".blue {background-color: rgb(5, 87, 180);}");
            client.print(".off{background-color: grey;}");
            client.print("button:hover{cursor: pointer; opacity: 0.7;}");
            client.print("</style>");
            client.print("<div class='container'>");
            client.print("<button class='red' type='submit' onmousedown='location.href=\"/RH\"'>ON</button>");
            client.print("<button class='off' type='submit' onmousedown='location.href=\"/RL\"'>OFF</button><br>");
            client.print("<button class='green' type='submit' onmousedown='location.href=\"/GH\"'>ON</button>");
            client.print("<button class='off' type='submit' onmousedown='location.href=\"/GL\"'>OFF</button><br>");
            client.print("<button class='blue' type='submit' onmousedown='location.href=\"/BH\"'>ON</button>");
            client.print("<button class='off' type='submit' onmousedown='location.href=\"/BL\"'>OFF</button>");
            client.print("</div>");


            // The HTTP response ends with another blank line:
            client.println();
            // break out of the while loop:
            break;
          } else {    // if you got a newline, then clear currentLine:
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }


        // Check to see if the client request was /X
        if (currentLine.endsWith("GET /RH")) {
          digitalWrite(LEDR, HIGH);
        }
        if (currentLine.endsWith("GET /RL")) {
          digitalWrite(LEDR, LOW);              
        }
        if (currentLine.endsWith("GET /GH")) {
          digitalWrite(LEDG, HIGH);              
        }
        if (currentLine.endsWith("GET /GL")) {
          digitalWrite(LEDG, LOW);           
        }
        if (currentLine.endsWith("GET /BH")) {
          digitalWrite(LEDB, HIGH);              
        }
        if (currentLine.endsWith("GET /BL")) {
          digitalWrite(LEDB, LOW);             
        }
      }
    }
    // close the connection:
    client.stop();
    Serial.println("client disconnected");
  }
}


void printWifiStatus() {
  // print the SSID of the network you're attached to:
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());


  // print your board's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);


  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
  // print where to go in a browser:
  Serial.print("To see this page in action, open a browser to http://");
  Serial.println(ip);
}

 

 

A short video of it working:

 

And the Serial Monitor output showing the HTTP transactions:

 

All-in-all a great job with the new documentation...